Program Stramosi; uses timp;
const patr : array[0..18] of longint=(1,2,4,8,16,32,64,128,256,512,1024,
                       2048,4096,8192,16384,32768,65536,131072,262144);
var m,n : longint;
    S : array[0..250000,0..17] of longint;
    log2 : array[1..250000] of integer;
    Intrare,Iesire : text;  t1 : real;

procedure Citeste;
var i : longint;
begin
  assign(Intrare,'stramosi.in');
  reset(Intrare);
  readln(Intrare,n,m);
  for i:=1 to n do read(Intrare,S[i,0]);
end;

procedure CalcLog2;
var i : longint;
    p : integer;
begin
  p:=0;
  while patr[p+1]-1<=n do
   begin
     for i:=patr[p] to patr[p+1]-1 do log2[i]:=p;
     p:=p+1;
   end;
  for i:=patr[p] to n do log2[i]:=p;
end;

procedure Calcule;
var i,j : longint;
begin
  CalcLog2;
  for i:=0 to 17 do S[0,i]:=0;
  for i:=1 to log2[n] do
   for j:=1 to n do S[j,i]:=S[S[j,i-1],i-1];
end;

procedure Procesare;
var i,Q,P : longint;
    lg : integer;
begin
  assign(Iesire,'stramosi.out');
  rewrite(Iesire);
  for i:=1 to m do
   begin
     readln(Intrare,Q,P);
     while (P>0) and (Q>0) do
      begin
        lg:=log2[P];
        Q:=S[Q,lg];
        P:=P-patr[lg];
      end;
     writeln(Iesire,Q);
   end;
  close(Intrare);
  close(Iesire);
end;

begin t1:=timpulcurent;
  Citeste;
  Calcule;
  Procesare; writeln(timpulcurent-t1:0:3); readln;
end.